
**Month-to-date over full previous month**

The month-to-date over full previous month compares the month-to-date against the entire previous month. Figure 15 shows that Sales MTD during April 2008 surpasses the total Sales Amount for March 2008. The Sales MTDOPM% provides an immediate comparison of the month-to-date with the total of the previous month; it shows growth over the previous month when the percentage is positive as is the case starting April 19, 2008.

 The month-to-date-over-previous-month growth is computed with the Sales MTDOPM % and Sales MTDOPM measures; these rely on the Sales MTD measure to compute the month-to-date value and on the Sales PMC measure to get the sales amount of the entire previous month:

Sales PMC :=

IF (

    [ShowValueForDates] && HASONEVALUE ( 'Date'[Year Month] ),

    CALCULATE (

        [Sales Amount],

        PARALLELPERIOD ( 'Date'[Date], -1, MONTH )

    )

)

Sales MTDOPM :=

VAR ValueCurrentPeriod = [Sales MTD]

VAR ValuePreviousPeriod = [Sales PMC]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod )

            && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales MTDOPM % :=

DIVIDE (

    [Sales MTDOPM],

    [Sales PMC]

)

The Sales PMC measure can also be written using [**PREVIOUSMONTH**](https://dax.guide/previousmonth/?aff=dax-patterns), as long as it is not used at the quarter or year level for more than one month:

Sales PMC (2) :=

IF (

    [ShowValueForDates] && HASONEVALUE ( 'Date'[Year Month] ),

    CALCULATE (

        [Sales Amount],

        PREVIOUSMONTH ( 'Date'[Date] )

    )

)